libgfaservices/remanent/remanent.pro

TEMPLATE = lib
CONFIG   += c++11
CONFIG   -= qt
CONFIG   += staticlib

QMAKE_CXXFLAGS_DEBUG += -Wno-unused-parameter -Wno-unused-but-set-variable
QMAKE_CXXFLAGS += -Wstrict-aliasing=0
# QMAKE_LIBS += -lm -lstdc++ -lgfaipc -ljsoncpp -pthread -l:libcommon.a -lmysqlclient
# QMAKE_LIBDIR += $$OUT_PWD/../common $$[QT_SYSROOT]/usr/lib/gfa
QMAKE_RPATHDIR += /usr/lib/gfa

QMAKE_CXXFLAGS += -D_REMANENT -D_LIBBUILD
QMAKE_CFLAGS += -D_REMANENT -D_LIBBUILD

_LIB_PATH = $$[QT_SYSROOT]/usr/lib/gfa/svc/
_INC_PATH = $$[QT_SYSROOT]/usr/include/gfa/svc/remanent/

CONFIG(debug, debug|release) {
	QMAKE_CXXFLAGS -= -Os
	QMAKE_CFLAGS -= -Os
    QMAKE_CXXFLAGS += -D_DEBUG
    QMAKE_CFLAGS += -D_DEBUG
	TARGET = remanentd
	QMAKE_CLEAN += libremanentd.a
}

CONFIG(release, debug|release) {
    QMAKE_CXXFLAGS += -Wno-unused-parameter -Wno-unused-but-set-variable
    QMAKE_CFLAGS += -Wno-unused-parameter -Wno-unused-but-set-variable
	TARGET = remanent
	QMAKE_CLEAN += libremanent.a
}

linux-buildroot-g++ {
    QMAKE_CXXFLAGS += -D_TARGET_BUILD
    QMAKE_CFLAGS += -D_TARGET_BUILD
    QMAKE_CXXFLAGS += -DSITARA_BUILD
    QMAKE_CFLAGS += -DSITARA_BUILD
}

INCLUDEPATH += ../ ../common $$(GEBGFADEV)

SOURCES += remstrvar.cpp \
    rembitvar.cpp \
    remvar.cpp \
    remvartbl.cpp \
    remlogger.cpp \
    dbpersist.cpp

HEADERS += \
    remvar.h \
    remlogger.h

includes.path = $$_INC_PATH
includes.extra += -$(INSTALL_FILE) $$PWD/remvar.h $(INSTALL_ROOT)$$includes.path
includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/remlogger.h $(INSTALL_ROOT)$$includes.path
includes.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/remvar.h
includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/remlogger.h
INSTALLS += includes

library.path = $$_LIB_PATH
library.extra += -$(INSTALL_FILE) $(TARGET) $(INSTALL_ROOT)$$library.path/$(TARGET)
library.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$library.path/$(TARGET)
INSTALLS += library