TEMPLATE = lib
VERSION = 1.0
CONFIG -= qt app_bundle
CONFIG += c++11 shared thread

####################################################################################

SOURCES += \
    src/gfaserial.c \
    src/gfamininetmst.c \
    src/gfamininetdev.c \
    src/gfabootlmast.c \
    src/dbghlp.c

linux-buildroot-g++ {
}

HEADERS += \
    src/gfamininetmst.h \
    src/gfamininetdev.h \
    src/gfagenericdev.h \
    src/gfaserial.h \
    src/gfabootlmast.h \
    src/dbghlp.h

####################################################################################

GFA_LIB_PATH = /usr/lib/gfa
GFA_INC_PATH = /usr/include/gfa
QMAKE_INCDIR += ti
QMAKE_RPATHLINKDIR += $$GFA_LIB_PATH
QMAKE_RPATHDIR += $$GFA_LIB_PATH
QMAKE_DEL_DIR = rmdir --ignore-fail-on-non-empty
QMAKE_LN_SHLIB = :

####################################################################################

CONFIG(debug, debug|release) {
    QMAKE_CXXFLAGS -= -Os
    QMAKE_CFLAGS -= -Os
    QMAKE_CXXFLAGS += -D_DEBUG
    QMAKE_CFLAGS += -D_DEBUG
	TARGET = $$join(TARGET,,,d)
}

####################################################################################

target.path = $$GFA_LIB_PATH
INSTALLS += target

####################################################################################

linux-g++ {
	includes.path = $$GFA_INC_PATH
	includes.extra += -$(INSTALL_FILE) $$PWD/src/gfamininetmst.h $(INSTALL_ROOT)$$includes.path
	includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/src/gfamininetdev.h $(INSTALL_ROOT)$$includes.path
	includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/src/gfagenericdev.h $(INSTALL_ROOT)$$includes.path
	includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/src/gfaserial.h $(INSTALL_ROOT)$$includes.path
	includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/src/gfabootlmast.h $(INSTALL_ROOT)$$includes.path
	includes.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/gfamininetmst.h
	includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/gfamininetdev.h
	includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/gfagenericdev.h
	includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/gfaserial.h
	includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/gfabootlmast.h
	INSTALLS += includes
}

####################################################################################

linux-buildroot-g++ {
	exists($$[QT_SYSROOT]) {
		library.path = $$[QT_SYSROOT]$$target.path
		library.extra += -$(INSTALL_PROGRAM) $(TARGET) $(INSTALL_ROOT)$$library.path/$(TARGET)
		library.extra += $$escape_expand(\\n\\t)-$(SYMLINK) $(TARGET) $(INSTALL_ROOT)$$library.path/$(TARGET0)
		library.extra += $$escape_expand(\\n\\t)-$(SYMLINK) $(TARGET) $(INSTALL_ROOT)$$library.path/$(TARGET1)
		library.extra += $$escape_expand(\\n\\t)-$(SYMLINK) $(TARGET) $(INSTALL_ROOT)$$library.path/$(TARGET2)
		library.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$library.path/$(TARGET)
		library.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$library.path/$(TARGET0)
		library.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$library.path/$(TARGET1)
		library.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$library.path/$(TARGET2)
		INSTALLS += library

		includes.path = $$[QT_SYSROOT]$$GFA_INC_PATH
		includes.extra += -$(INSTALL_FILE) $$PWD/src/gfamininetmst.h $(INSTALL_ROOT)$$includes.path
		includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/src/gfamininetdev.h $(INSTALL_ROOT)$$includes.path
		includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/src/gfagenericdev.h $(INSTALL_ROOT)$$includes.path
		includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/src/gfaserial.h $(INSTALL_ROOT)$$includes.path
		includes.extra += $$escape_expand(\\n\\t)-$(INSTALL_FILE) $$PWD/src/gfabootlmast.h $(INSTALL_ROOT)$$includes.path
		includes.uninstall += -$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/gfamininetmst.h
		includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/gfamininetdev.h
		includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/gfagenericdev.h
		includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/gfaserial.h
		includes.uninstall += $$escape_expand(\\n\\t)-$(DEL_FILE) $(INSTALL_ROOT)$$includes.path/gfabootlmast.h
		INSTALLS += includes

		itoolchain.target = install_toolchain
		itoolchain.depends = install_library install_includes
		QMAKE_EXTRA_TARGETS += itoolchain

		utoolchain.target = uninstall_toolchain
		utoolchain.depends = uninstall_library uninstall_includes
		QMAKE_EXTRA_TARGETS += utoolchain
	}
    QMAKE_CXXFLAGS += -D_TARGET_BUILD
    QMAKE_CFLAGS += -D_TARGET_BUILD
}

####################################################################################

deploylib.target = deploylib
deploylib.commands = @echo BASENAME="$(QMAKE_TARGET)" > deploytargets
deploylib.commands += $$escape_expand(\\n\\t)@echo TARGET="$(TARGET)" >> deploytargets
deploylib.commands += $$escape_expand(\\n\\t)@echo TARGET0="$(TARGET0)" >> deploytargets
deploylib.commands += $$escape_expand(\\n\\t)@echo TARGET1="$(TARGET1)" >> deploytargets
deploylib.commands += $$escape_expand(\\n\\t)@echo TARGET2="$(TARGET2)" >> deploytargets
deploylib.commands += $$escape_expand(\\n\\t)@echo HEADERS="\\\"gfamininetmst.h gfamininetdev.h gfagenericdev.h gfaserial.h gfabootlmast.h\\\"" >> deploytargets
PRE_TARGETDEPS += deploylib
QMAKE_EXTRA_TARGETS += deploylib